+import msp_interface;
+import common;
+import shadow;
+
+const bool use_base_color_map = false;
+const bool use_metalness_map = false;
+const bool use_roughness_map = false;
+const bool use_occlusion_map = false;
+const bool use_emission = false;
+const bool use_emission_map = false;
+
+const float PI = 3.1415926535;
+
+#pragma MSP stage(fragment)
+vec4 get_base_color()
+{
+ if(use_base_color_map)
+ return texture(base_color_map, texcoord.xy);
+ else
+ return pbr_material.base_color;
+}
+
+float get_metalness_value()
+{
+ if(use_metalness_map)
+ return texture(metalness_map, texcoord.xy).r;
+ else
+ return pbr_material.metalness;
+}
+
+float get_roughness_value()
+{
+ if(use_roughness_map)
+ return texture(roughness_map, texcoord.xy).r;
+ else
+ return pbr_material.roughness;
+}
+
+float get_occlusion_value()
+{
+ if(use_occlusion_map)
+ return texture(occlusion_map, texcoord.xy).r;
+ else
+ return 1.0;
+}
+
+vec3 get_emission_color()
+{
+ if(use_emission_map)
+ return texture(emission_map, texcoord.xy).rgb;
+ else
+ return basic_material.emission.rgb;
+}
+
+/* Computes the diffuse reflection of the macrosurface */
+vec3 lambert_diffuse(vec3 base_color)
+{
+ // Scale by pi to get a result per steradian, suitable for integration
+ return base_color/PI;
+}
+
+/* Computes the fraction of microfacets aligned at the halfway vector
+(Trowbridge-Reitz GGX) */
+float normal_distribution_ggxtr(vec3 normal, vec3 halfway, float roughness)
+{
+ float n_dot_h = max(dot(normal, halfway), 0.0);
+ //return n_dot_h;
+ float rough_q = roughness * roughness;
+ rough_q *= rough_q;
+ float denom = n_dot_h*n_dot_h*(rough_q-1)+1;
+ //return (n_dot_h*n_dot_h-0.8)*5.0;
+ //return rough_q*10;
+ // Scale by pi to get a result per steradian, suitable for integration
+ return rough_q/(PI*denom*denom);
+}
+
+/* Computes shadowing and masking of a microfacet surface from a given
+direction */
+float geometry_schlick_ggx(vec3 normal, vec3 view, float k)
+{
+ float n_dot_v = max(dot(normal, view), 0.0);
+ return n_dot_v/(n_dot_v*(1.0-k)+k);
+}
+
+/* Computes shadowing and masking of a microfacet surface for a combination of
+look and light directions */
+float geometry_smith(vec3 normal, vec3 look, vec3 light, float roughness)
+{
+ float k = (roughness+1.0)*(roughness+1.0)/8.0;
+ float ggx_look = geometry_schlick_ggx(normal, look, k);
+ float ggx_light = geometry_schlick_ggx(normal, light, k);
+ return ggx_look*ggx_light;
+}
+
+/* Computes the reflectance of the material at a given reflection angle */
+vec3 fresnel_schlick(vec3 halfway, vec3 look, vec3 base_color, float metalness)
+{
+ // 0.04 is a decent approximation for dielectric base reflectivity
+ vec3 f0 = mix(vec3(0.04), base_color, metalness);
+ return mix(f0, vec3(1.0), pow(1.0-dot(halfway, look), 5.0));
+}
+
+/* Computes the full contribution of a single light */
+vec3 cooktorrance_one_light_direct(vec3 normal, vec3 look, vec3 light, vec3 light_color, vec3 base_color, float metalness, float roughness)
+{
+ vec3 halfway = normalize(light-look);
+ //return normal;
+ float ndist = normal_distribution_ggxtr(normal, halfway, roughness);
+ float geom = geometry_smith(normal, -look, light, roughness);
+ //return vec3(ndist);
+
+ vec3 k_spec = fresnel_schlick(halfway, light, base_color, metalness);
+ vec3 k_diff = (1.0-k_spec)*(1.0-metalness);
+
+ float denom = max(4.0*max(dot(normal, -look), 0.0)*max(dot(normal, light), 0.0), 0.001);
+ return max(dot(normal, light), 0.0)*(k_diff*lambert_diffuse(base_color)+k_spec*ndist*geom/denom);
+}
+
+vec3 cooktorrance_lighting(vec3 normal, vec3 look, vec3 base_color, float metalness, float roughness)
+{
+ vec3 light;
+ if(use_normal_map)
+ light = normalize(tbn_light_dir);
+ else
+ light = normalize(eye_light_dir);
+
+ float shadow = get_shadow_factor(0);
+ vec3 color = cooktorrance_one_light_direct(normal, look, light, light_sources[0].diffuse.rgb, base_color, metalness, roughness)*shadow;
+
+ color *= get_occlusion_value();
+
+ if(use_emission)
+ color += get_emission_color();
+
+ return color;
+}
+
+void main()
+{
+ vec3 normal;
+ vec3 look;
+ if(use_normal_map)
+ {
+ normal = get_fragment_normal();
+ look = normalize(tbn_look_dir);
+ }
+ else
+ {
+ normal = normalize(eye_normal);
+ look = normalize(eye_look_dir);
+ }
+
+ vec4 base_color = get_base_color();
+ float metalness = get_metalness_value();
+ float roughness = get_roughness_value();
+
+ vec3 lit_color = cooktorrance_lighting(normal, look, base_color.rgb, metalness, roughness);
+
+ frag_color = vec4(lit_color, base_color.a);
+}