shaderlib/cooktorrance.glsl

   1 import msp_interface;
   2 import common;
   3 import shadow;
   4
   5 struct PbrMaterialParameters
   6 {
   7         vec4 base_color;
   8         vec4 emission;
   9         float metalness;
  10         float roughness;
  11 };
  12
  13 uniform PbrMaterial
  14 {
  15         PbrMaterialParameters pbr_material;
  16 };
  17
  18 uniform sampler2D base_color_map;
  19 uniform sampler2D metalness_map;
  20 uniform sampler2D roughness_map;
  21 uniform sampler2D occlusion_map;
  22 uniform sampler2D emission_map;
  23
  24 layout(constant_id=auto) const bool use_base_color_map = false;
  25 layout(constant_id=auto) const bool use_metalness_map = false;
  26 layout(constant_id=auto) const bool use_roughness_map = false;
  27 layout(constant_id=auto) const bool use_occlusion_map = false;
  28 layout(constant_id=auto) const bool use_emission = false;
  29 layout(constant_id=auto) const bool use_emission_map = false;
  30
  31 const float PI = 3.1415926535;
  32
  33 #pragma MSP stage(fragment)
  34 virtual vec4 get_base_color()
  35 {
  36         if(use_base_color_map)
  37                 return texture(base_color_map, texcoord.xy);
  38         else
  39                 return pbr_material.base_color;
  40 }
  41
  42 virtual float get_metalness_value()
  43 {
  44         if(use_metalness_map)
  45                 return texture(metalness_map, texcoord.xy).r;
  46         else
  47                 return pbr_material.metalness;
  48 }
  49
  50 virtual float get_roughness_value()
  51 {
  52         if(use_roughness_map)
  53                 return texture(roughness_map, texcoord.xy).r;
  54         else
  55                 return pbr_material.roughness;
  56 }
  57
  58 virtual float get_occlusion_value()
  59 {
  60         if(use_occlusion_map)
  61                 return texture(occlusion_map, texcoord.xy).r;
  62         else
  63                 return 1.0;
  64 }
  65
  66 virtual vec3 get_emission_color()
  67 {
  68         if(use_emission_map)
  69                 return texture(emission_map, texcoord.xy).rgb;
  70         else
  71                 return pbr_material.emission.rgb;
  72 }
  73
  74 /* Computes the diffuse reflection of the macrosurface */
  75 vec3 lambert_diffuse(vec3 base_color)
  76 {
  77         // Scale by pi to get a result per steradian, suitable for integration
  78         return base_color/PI;
  79 }
  80
  81 /* Computes the fraction of microfacets aligned at the halfway vector
  82 (Trowbridge-Reitz GGX) */
  83 float normal_distribution_ggxtr(vec3 normal, vec3 halfway, float roughness)
  84 {
  85         float n_dot_h = max(dot(normal, halfway), 0.0);
  86         float rough_q = roughness * roughness;
  87         rough_q *= rough_q;
  88         float denom = n_dot_h*n_dot_h*(rough_q-1)+1;
  89         /* Scale by pi to normalize the total area of the microfacets as projected
  90         to the macrosurface */
  91         return rough_q/(PI*denom*denom);
  92 }
  93
  94 /* Computes shadowing and masking of a microfacet surface from a given
  95 direction */
  96 float geometry_schlick_ggx(vec3 normal, vec3 view, float k)
  97 {
  98         float n_dot_v = max(dot(normal, view), 0.0);
  99         return n_dot_v/(n_dot_v*(1.0-k)+k);
 100 }
 101
 102 /* Computes shadowing and masking of a microfacet surface for a combination of
 103 look and light directions */
 104 float geometry_smith(vec3 normal, vec3 look, vec3 light, float roughness)
 105 {
 106         float k = (roughness+1.0)*(roughness+1.0)/8.0;
 107         float ggx_look = geometry_schlick_ggx(normal, look, k);
 108         float ggx_light = geometry_schlick_ggx(normal, light, k);
 109         return ggx_look*ggx_light;
 110 }
 111
 112 /* Computes the reflectance of the material at a given reflection angle */
 113 vec3 fresnel_schlick(vec3 halfway, vec3 look, vec3 base_color, float metalness)
 114 {
 115         // 0.04 is a decent approximation for dielectric base reflectivity
 116         vec3 f0 = mix(vec3(0.04), base_color, metalness);
 117         return mix(f0, vec3(1.0), pow(max(1.0-dot(halfway, look), 0.0), 5.0));
 118 }
 119
 120 /* Computes the full contribution of a single light */
 121 vec3 cooktorrance_one_light_direct(vec3 normal, vec3 look, vec3 light, vec3 light_color, vec3 base_color, float metalness, float roughness)
 122 {
 123         vec3 halfway = normalize(light-look);
 124         float ndist = normal_distribution_ggxtr(normal, halfway, roughness);
 125         float geom = geometry_smith(normal, -look, light, roughness);
 126
 127         vec3 k_spec = fresnel_schlick(halfway, light, base_color, metalness);
 128         vec3 k_diff = (1.0-k_spec)*(1.0-metalness);
 129
 130         float spec_denom = max(4.0*max(dot(normal, -look), 0.0)*max(dot(normal, light), 0.0), 0.001);
 131         return max(dot(normal, light), 0.0)*light_color*(k_diff*lambert_diffuse(base_color)+k_spec*ndist*geom/spec_denom);
 132 }
 133
 134 vec3 cooktorrance_lighting(vec3 normal, vec3 look, vec3 base_color, float metalness, float roughness)
 135 {
 136         vec3 light = normalize(world_light_dir);
 137
 138         float shadow = get_shadow_factor(0);
 139         vec3 color = cooktorrance_one_light_direct(normal, look, light, light_sources[0].color, base_color, metalness, roughness)*shadow;
 140
 141         color *= get_occlusion_value();
 142
 143         if(use_emission)
 144                 color += get_emission_color();
 145
 146         return color;
 147 }
 148
 149 void main()
 150 {
 151         vec3 normal = get_fragment_normal();
 152         vec3 look = normalize(world_look_dir);
 153
 154         vec4 base_color = get_base_color();
 155         float metalness = get_metalness_value();
 156         float roughness = get_roughness_value();
 157
 158         vec3 lit_color = cooktorrance_lighting(normal, look, base_color.rgb, metalness, roughness);
 159
 160         frag_color = vec4(lit_color, base_color.a);
 161 }