demos/forestpond/data/fluidsim_integrate.glsl

   1 import fluidsim;
   2
   3 #pragma MSP stage(compute)
   4 float get_clamping(float depth, float v_right, float v_up, float v_left, float v_down)
   5 {
   6         float total_out = max(v_right, 0.0)+max(v_up, 0.0)-min(v_left, 0.0)-min(v_down, 0.0);
   7         return min(max_flow_fraction/max(total_out*delta_time, max_flow_fraction), depth/residual_depth);
   8 }
   9
  10 void main()
  11 {
  12         ivec2 size = imageSize(surface_out);
  13         ivec2 coord = ivec2(gl_GlobalInvocationID.xy)+1;
  14         if(coord.x>=size.x-1 || coord.y>=size.y-1)
  15                 return;
  16
  17         vec4 data = get_data(coord);
  18         vec4 right_data = get_data(coord+ivec2(1, 0));
  19         vec4 up_data = get_data(coord+ivec2(0, 1));
  20         vec4 left_data = get_data(coord-ivec2(1, 0));
  21         vec4 down_data = get_data(coord-ivec2(0, 1));
  22
  23         float ul_vx = texelFetch(velocity_in, coord+ivec2(-1, 1), 0).x;
  24         float left2_vx = texelFetch(velocity_in, coord-ivec2(2, 0), 0).x;
  25         vec2 dl_velocity = texelFetch(velocity_in, coord-ivec2(1, 1), 0).xy;
  26         float down2_vy = texelFetch(velocity_in, coord-ivec2(0, 2), 0).y;
  27         float dr_vy = texelFetch(velocity_in, coord+ivec2(1, -1), 0).y;
  28
  29         float clamping = get_clamping(data.w, data.x, data.y, left_data.x, down_data.y);
  30         float right_cl = get_clamping(right_data.w, right_data.x, right_data.y, data.x, dr_vy);
  31         float up_cl = get_clamping(up_data.w, up_data.x, up_data.y, ul_vx, data.y);
  32         float left_cl = get_clamping(left_data.w, left_data.x, left_data.y, left2_vx, dl_velocity.y);
  33         float down_cl = get_clamping(down_data.w, down_data.x, down_data.y, dl_velocity.x, down2_vy);
  34
  35         // Integration step: change surface level based on velocities
  36         float total_flow_out = data.x*mix(data.w*clamping, right_data.w*right_cl, data.x<0)+
  37                 data.y*mix(data.w*clamping, up_data.w*up_cl, data.y<0)-
  38                 left_data.x*mix(data.w*clamping, left_data.w*left_cl, left_data.x>0)-
  39                 down_data.y*mix(data.w*clamping, down_data.w*down_cl, down_data.y>0);
  40         float new_surface = data.z-total_flow_out*delta_time;
  41
  42         imageStore(surface_out, coord, vec4(new_surface, 0.0, 0.0, 0.0));
  43 }