demos/desertpillars/data/sphere_morph.glsl

   1 uniform Morph
   2 {
   3         float morph;
   4 };
   5
   6 const float PI = 3.1415926535;
   7 const float OFFSET = 0.001;
   8
   9 #pragma MSP stage(vertex)
  10 vec3 deform(vec3 p)
  11 {
  12         vec3 d = cos(p*(2.0*PI)+morph)*0.05;
  13         return p*(1.0+(d.x+d.y+d.z)*sin(morph*0.2));
  14 }
  15
  16 vec4 get_vertex_position() override
  17 {
  18         return vec4(deform(vertex.xyz), 1.0);
  19 }
  20
  21 vec3 get_vertex_normal() override
  22 {
  23         vec3 tangent;
  24         if(abs(normal.x)>abs(normal.y))
  25                 tangent = normalize(vec3(-normal.z, 0.0, normal.x));
  26         else
  27                 tangent = normalize(vec3(0.0, -normal.z, normal.y));
  28         vec3 binormal = cross(normal, tangent);
  29
  30         vec3 xn = deform(vertex.xyz-tangent*OFFSET);
  31         vec3 xp = deform(vertex.xyz+tangent*OFFSET);
  32         vec3 yn = deform(vertex.xyz-binormal*OFFSET);
  33         vec3 yp = deform(vertex.xyz+binormal*OFFSET);
  34
  35         return normalize(cross(xp-xn, yp-yn));
  36 }