import lighting;

struct ShadowParameters
{
	int type;
	float darkness;
	int matrix_index;
	vec4 region;
	vec2 bias;
};

layout(set=0) uniform ShadowMap
{
	ShadowParameters shadows[max_lights];
	mat4 shd_world_matrix[max_lights*4];
};

layout(set=0) uniform sampler2DShadow shadow_map;

layout(constant_id=auto) const bool use_shadow_map = false;

#pragma MSP stage(fragment)
virtual float get_shadow_factor(int index, vec4 world_pos)
{
	if(use_shadow_map)
	{
		int type = shadows[index].type;
		vec3 shadow_coord;
		if(type==1)
		{
			shadow_coord = (shd_world_matrix[shadows[index].matrix_index]*world_pos).xyz;
			shadow_coord.z -= shadows[index].bias.x;
		}
		else if(type==2)
		{
			int base = shadows[index].matrix_index;
			vec4 clip_coord = shd_world_matrix[base]*world_pos;
			for(int i=1; i<4; ++i)
			{
				vec4 c = shd_world_matrix[base+i]*world_pos;
				if(c.w>clip_coord.w)
					clip_coord = c;
			}
			shadow_coord = clip_coord.xyz/clip_coord.w;
			vec2 bias = shadows[index].bias;
			shadow_coord.z = (shadow_coord.z+bias.x)/bias.y-bias.x;
		}
		else
			return 1.0;

		if(shadow_coord.x<0 || shadow_coord.x>1 || shadow_coord.y<0 || shadow_coord.y>1)
			return 1.0;

		vec4 region = shadows[index].region;
		float shadow_sample = texture(shadow_map, vec3(shadow_coord.xy*region.zw+region.xy, min(shadow_coord.z, 1.0)));
		return mix(1.0, shadow_sample, shadows[index].darkness);
	}
	else
		return 1.0;
}