import msp_interface;
import shadow;

uniform EnvMap
{
	mat3 env_world_matrix;
};

uniform sampler2D normal_map;
uniform samplerCube environment_map;
uniform samplerCube irradiance_map;

layout(constant_id=auto) const bool use_normal_map = false;

#pragma MSP stage(vertex)
virtual vec4 get_vertex_position()
{
	return vertex;
}

virtual vec3 get_vertex_normal()
{
	return normal;
}

virtual mat4 get_vertex_transform()
{
	return world_obj_matrix;
}

virtual mat3 get_normal_transform()
{
	return world_obj_normal_matrix;
}

void standard_transform()
{
	mat4 vertex_tf = get_vertex_transform();
	mat3 normal_tf = get_normal_transform();

	vec4 world_vertex = vertex_tf*get_vertex_position();
	vec4 eye_vertex = eye_world_matrix*world_vertex;
	gl_Position = clip_eye_matrix*eye_vertex;

	out vec3 world_normal = normal_tf*get_vertex_normal();
	vec3 world_tangent = normal_tf*tangent;
	vec3 world_binormal = cross(world_normal, world_tangent);
	out mat3 world_tbn_matrix = mat3(world_tangent, world_binormal, world_normal);

	vec3 eye_pos = (inverse(eye_world_matrix)*vec4(0.0, 0.0, 0.0, 1.0)).xyz;
	out vec3 world_look_dir = normalize(world_vertex.xyz-eye_pos);

	out vec3 world_light_dir = light_sources[0].position.xyz-world_vertex.xyz*light_sources[0].position.w;

	out vec3 world_halfway_dir = normalize(world_light_dir-world_look_dir);

	out float fog_coord = eye_vertex.z;

	if(use_clipping)
	{
		for(int i=0; i<max_clip_planes; ++i)
			gl_ClipDistance[i] = dot(world_vertex, clip_planes[i].equation);
	}

	shadow_transform(world_vertex);
}

virtual void custom_transform()
{
}

void main()
{
	standard_transform();
	custom_transform();
	passthrough;
}

#pragma MSP stage(fragment)
virtual vec3 get_fragment_normal()
{
	if(use_normal_map)
		return normalize(world_tbn_matrix*(texture(normal_map, texcoord.xy).xyz*2.0-1.0));
	else
		return normalize(world_normal);
}

virtual vec3 get_environment_sample(vec3 direction, float roughness)
{
	float lod = (2-roughness)*roughness*(textureQueryLevels(environment_map)-1);
	return textureLod(environment_map, env_world_matrix*direction, lod).rgb;
}

virtual vec3 get_reflection(vec3 normal, vec3 look)
{
	vec3 reflect_dir = reflect(look, normal);
	return get_environment_sample(reflect_dir, 0.0);
}

virtual vec3 get_irradiance_sample(vec3 normal)
{
	return texture(irradiance_map, env_world_matrix*normal).rgb;
}

vec3 apply_fog(vec3 color)
{
	float fog_value = exp(fog_coord*fog_density);
	return mix(fog_color.rgb, color, fog_value);
}