import msp_interface;
import shadow;

uniform EnvMap
{
	mat3 env_eye_matrix;
};

uniform sampler2D normal_map;
uniform samplerCube environment_map;

layout(constant_id=auto) const bool use_normal_map = false;

#pragma MSP stage(vertex)
virtual vec4 get_vertex_position()
{
	return vertex;
}

virtual vec3 get_vertex_normal()
{
	return normal;
}

virtual vec4 transform_position(vec4 pos)
{
	return eye_obj_matrix*pos;
}

virtual vec3 transform_normal(vec3 nor)
{
	return eye_obj_normal_matrix*nor;
}

void standard_transform()
{
	out vec4 eye_vertex = transform_position(get_vertex_position());
	gl_Position = projection_matrix*eye_vertex;

	out vec3 eye_normal = transform_normal(get_vertex_normal());
	vec3 eye_tangent = transform_normal(tangent);
	vec3 eye_binormal = transform_normal(binormal);
	out mat3 eye_tbn_matrix = mat3(eye_tangent, eye_binormal, eye_normal);

	out vec3 eye_look_dir = normalize(eye_vertex.xyz);
	out vec3 tbn_look_dir = eye_look_dir*eye_tbn_matrix;

	out vec3 eye_light_dir = normalize(light_sources[0].position.xyz-eye_vertex.xyz*light_sources[0].position.w);
	out vec3 tbn_light_dir = eye_light_dir*eye_tbn_matrix;

	out vec3 eye_halfway_dir = normalize(eye_light_dir-eye_look_dir);
	out vec3 tbn_halfway_dir = eye_halfway_dir*eye_tbn_matrix;

	out vec3 tbn_zenith_dir = eye_zenith_dir*eye_tbn_matrix;
	out float fog_coord = eye_vertex.z;

	for(int i=0; i<max_clip_planes; ++i)
		gl_ClipDistance[i] = dot(eye_vertex, clip_planes[i].equation);

	shadow_transform(eye_vertex);
}

virtual void custom_transform()
{
}

void main()
{
	standard_transform();
	custom_transform();
	passthrough;
}

#pragma MSP stage(fragment)
virtual vec3 get_fragment_normal()
{
	if(use_normal_map)
		return normalize(texture(normal_map, texcoord.xy).xyz*2.0-1.0);
	else
		return vec3(0.0, 0.0, 1.0);
}

virtual vec4 get_environment_sample(vec3 direction)
{
	return texture(environment_map, direction);
}

virtual vec3 get_reflection(vec3 normal, vec3 look)
{
	vec3 reflect_dir = reflect(look, normal);
	if(use_normal_map)
		reflect_dir = eye_tbn_matrix*reflect_dir;

	return get_environment_sample(env_eye_matrix*reflect_dir).rgb;
}

vec3 apply_fog(vec3 color)
{
	float fog_value = exp(fog_coord*fog_density);
	return mix(fog_color.rgb, color, fog_value);
}